home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / mint / mint96sb.zoo / src / quickzer.spp < prev    next >
Encoding:
Text File  |  1992-10-05  |  869 b   |  37 lines
  1. ;
  2. ; quickzero(char *place, long size): zero an area of memory. "size" is
  3. ; the number of 256 byte blocks in the area, and must be > 0.
  4. ; registers changed: d0 and a0
  5. ;
  6.     TEXT
  7.     
  8.     XDEF    _quickzero
  9. _quickzero:
  10.     move.l    4(sp),a0    ; place to zero at
  11.     move.l    8(sp),d0    ; number of blocks
  12.     movem.l    d1-d7/a1,-(sp)    ; save registers
  13.     moveq.l    #0,d1        ; zero them out
  14.     moveq.l    #0,d2
  15.     moveq.l    #0,d3
  16.     moveq.l    #0,d4
  17.     moveq.l    #0,d5
  18.     moveq.l    #0,d6
  19.     moveq.l    #0,d7
  20.     move.l    d1,a1
  21.     subq.l    #1,d0        ; adjust for dbra loop
  22. loop:
  23.     movem.l    d1-d7/a1,(a0)    ; zero the memory, 32 bytes at a time
  24.     movem.l    d1-d7/a1,32(a0)
  25.     movem.l    d1-d7/a1,64(a0)
  26.     movem.l    d1-d7/a1,96(a0)
  27.     movem.l    d1-d7/a1,128(a0)
  28.     movem.l    d1-d7/a1,160(a0)
  29.     movem.l    d1-d7/a1,192(a0)
  30.     movem.l    d1-d7/a1,224(a0)
  31.     lea    256(a0),a0
  32.     dbra    d0,loop
  33. ;
  34.     movem.l    (sp)+,d1-d7/a1    ; restore regs
  35.     rts            ; and leave
  36.     END
  37.